Re [de-users] Mailversand per Makro mit Simple Mail Message

de-users
#1

Zur Thunderbird-Problematik habe ich leider keine weiteren Ideen, aber:

Es berührt diesen Thread zwar nur am Rande, aber ich denke, eine kleine "sub" (s.u. - betriebssystem-unabhängig) zum Mail-Versand ist für andere LO-Nutzer vielleicht auch ganz interessant und/oder nützlich. Ich habe heute auch erst durch Roberts Thread mitbekommen, dass man so etwas machen kann ...

Viele Grüße und einen schönen Abend noch
Hans-Werner :-))

   Sub MailVersand

      Dim A as String ' An
      Dim aC() as String ' arr Cc
      Dim aB() as String ' arr Bcc
      Dim B as String ' Betreff
      Dim aA() as String ' arr Anhang
      Dim T as String ' Text

      Dim oMA as Object ' obj Mail Agent
      Dim oMC as Object ' obj Mail Client
      Dim oMM as Object ' obj Mail Message

      Const SSM = "com.sun.star.system.SimpleSystemMail"
      Const SCM = "com.sun.star.system.SimpleCommandMail"

' An:
      A = "OoOHWHOoO@t-online.de"
' Kopie:
      aC = Array("HansWernerHerold@t-online.de")
' Blindkopie:
      aB = Array()
' Betreff:
      B = "CORONA NEWS " & CDate(date)
' Anhang:
      aA = Array(ConvertToUrl("E:\TMP\CALC.ods") ,_
                 ConvertToUrl("E:\TMP\WRITER.odt"))
' Mailtext:
      T = "Community-basiertes Projekt:" & Chr(10) &_
           " " & Chr(10) &_
           "https://coronatracker.org/" & Chr(10) &_
           " " & Chr(10) &_
           "Grüße" & Chr(10) &_
           "Hans-Werner ;-))"

      If ((GetGUIType() = 1) Or (GetGUIType() = 4)) Then
         oMA = CreateUnoService(IIf(GetGUIType() = 1,SSM,SCM))
      Else
         MsgBox("Betriebssystem weder Windows noch Linux !") : End
      EndIf

      oMC = oMA.querySimpleMailClient()
      oMM = oMC.createSimpleMailMessage()

      If (A <> "") Then : oMM.setRecipient(A) : EndIf
      If (UBound(aC) <> -1) Then : oMM.setCcRecipient(aC) : EndIf
      If (UBound(aB) <> -1) Then : oMM.setBccRecipient(aB) : EndIf
      If (B <> "") Then : oMM.setSubject(B) : EndIF
      If (UBound(aA) <> -1) Then : oMM.setAttachement(aA) : EndIf
      If (T <> "") Then : oMM.Body = T : EndIf

      oMC.sendSimpleMailMessage(oMM,0)

   End Sub