Calc: Vorlagen in Formeln zu weisen

de-users
#1

Liebe Liste,

ich stehe zur Zeit wohl etwas auf dem Schlauch. Ich versuche per Formel
einer Zelle sowohl einen Inhalt als auch eine Vorlage zuzuweisen.
Die Formel:
=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr.
Himmelfahrt";"")+VORLAGE(WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"grau";"weiss"))
Ohne die Vorlagendefinition schreibt mir das bei dem entsprechenden
Kalenderfeld "Chr. Himmelfahrt" rein. Sobald ich "+ VORLAGE ..." da
stehen habe wird das Feld grau - und in dem Feld steht nur noch #Wert.

Die Formel "VORLAGE ..." produziert bei mir merkwürdigerweise, allein
stehend, lauter 0-Werte - war früher meines Wissens nicht so. Diese
0-Werte kann ich über T(VORLAGE ...) eliminieren - nur kann ich dann
nicht mehr Formel und Vorlage kombinieren.

Gruß

Robert

#2

Hallo,

Die Formel "VORLAGE ..." produziert bei mir merkwürdigerweise, allein
stehend, lauter 0-Werte - war früher meines Wissens nicht so.

sicher? Ich zitiere mal aus der Hilfe:

Diese Funktion gibt immer den Wert 0 zurück, so dass Sie die
Funktion per Addition zu einer anderen Funktion hinzufügen können,
ohne deren Wert zu verändern.

--> Sieht so aus, als solle das so sein.

Diese 0-Werte kann ich über T(VORLAGE ...) eliminieren - nur kann ich
dann nicht mehr Formel und Vorlage kombinieren.

Willst Du die Nullwerte nicht angezeigt bekommen (dafür gibt es eine
Option unter Calc --> Ansicht), oder was willst Du genau?

#3

Hallo Robert

ich stehe zur Zeit wohl etwas auf dem Schlauch. Ich versuche per Formel
einer Zelle sowohl einen Inhalt als auch eine Vorlage zuzuweisen.
Die Formel:
=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr.
Himmelfahrt";"")+VORLAGE(WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"grau";"weiss"))
Ohne die Vorlagendefinition schreibt mir das bei dem entsprechenden
Kalenderfeld "Chr. Himmelfahrt" rein. Sobald ich "+ VORLAGE ..." da
stehen habe wird das Feld grau - und in dem Feld steht nur noch #Wert.

Die Formel "VORLAGE ..." produziert bei mir merkwürdigerweise, allein
stehend, lauter 0-Werte - war früher meines Wissens nicht so. Diese
0-Werte kann ich über T(VORLAGE ...) eliminieren - nur kann ich dann
nicht mehr Formel und Vorlage kombinieren.

Des Rätsels Lösung liegt in Deinem "Schlusswort": VORLAGE() produziert den 0-Wert. Wenn Du diesen Null-Wert an einen Text anfügen willst, produzierst Du damit die Fehlermeldung #WERT! Die Lösung hierzu findest Du in der Hilfe. Zudem: Du musst unmittelbar an den Wert anhängen. Mein "verkürzter" Vorschlag für Dein Problem:

=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr. Himmelfahrt"&T(VORLAGE("grau"));"leer"+VORLAGE("weiss"))

Hoffe, das hilft Dir weiter.

Freundlich grüsst

Ernst

#4

Uups - sorry, ging etwas schnell raus!

Hallo Robert

ich stehe zur Zeit wohl etwas auf dem Schlauch. Ich versuche per Formel
einer Zelle sowohl einen Inhalt als auch eine Vorlage zuzuweisen.
Die Formel:
=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr.
Himmelfahrt";"")+VORLAGE(WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"grau";"weiss"))

Ohne die Vorlagendefinition schreibt mir das bei dem entsprechenden
Kalenderfeld "Chr. Himmelfahrt" rein. Sobald ich "+ VORLAGE ..." da
stehen habe wird das Feld grau - und in dem Feld steht nur noch #Wert.

Die Formel "VORLAGE ..." produziert bei mir merkwürdigerweise, allein
stehend, lauter 0-Werte - war früher meines Wissens nicht so. Diese
0-Werte kann ich über T(VORLAGE ...) eliminieren - nur kann ich dann
nicht mehr Formel und Vorlage kombinieren.

Des Rätsels Lösung liegt in Deinem "Schlusswort": VORLAGE() produziert den 0-Wert. Wenn Du diesen Null-Wert an einen Text anfügen willst, produzierst Du damit die Fehlermeldung #WERT! Die Lösung hierzu findest Du in der Hilfe. Zudem: Du musst unmittelbar an den Wert anhängen. Mein "verkürzter" Vorschlag für Dein Problem:

=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr. Himmelfahrt"&T(VORLAGE("grau"));"leer"+VORLAGE("weiss"))

Besser (weil richtig[er]):

=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr. Himmelfahrt"&T(VORLAGE("grau"));"leer"&T(VORLAGE("weiss")))

Hoffe, das hilft jetzt definitiv.

Freundlich grüsst

Ernst

#5

ich stehe zur Zeit wohl etwas auf dem Schlauch. Ich versuche per Formel
einer Zelle sowohl einen Inhalt als auch eine Vorlage zuzuweisen.
Die Formel:
=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr.
Himmelfahrt";"")+VORLAGE(WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"grau";"weiss"))

Erstens kann man mit *Texten* ("Chr. Himmelfahrt") keine mathematische
Operation ('+') ausführen; der Operator für Verknüpfungen von Texten
lautet '&'.

Zweitens fragst Du zweimal die gleiche Bedingung ab; das ist
umständlich. Einfacher (und übersichtlicher und verständlicher) wäre

=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr.

Himmelfahrt"&T(VORLAGE("grau"));""&T(VORLAGE("weiss")))

Und drittens benötigt man für den ELSE-Zweig eigentlich /überhaupt/
keine Formatvorlage, denn im Zweifelsfall fällt man ja auf die
stinknormale Zellenformatierung zurück. Daher reicht auch ein

=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr.

Himmelfahrt"&T(VORLAGE("grau"));"")

Ohne die Vorlagendefinition schreibt mir das bei dem entsprechenden
Kalenderfeld "Chr. Himmelfahrt" rein.

Also trifft die Bedingung zu.

Sobald ich "+ VORLAGE ..." da
stehen habe wird das Feld grau

So soll es doch auch sein, wenn die Bedingung zutrifft, oder?

- und in dem Feld steht nur noch #Wert.

Jepp; ein Text ist nun mal kein Wert, mit dem man mathematische
Operationen (hier Addition) ausführen kann (s. o.).

Die Formel "VORLAGE ..." produziert bei mir merkwürdigerweise, allein
stehend, lauter 0-Werte - war früher meines Wissens nicht so.

Doch; das steht sogar *explizit* in der Hilfe drin.

Diese 0-Werte kann ich über T(VORLAGE ...) eliminieren -

Auch *darauf* wird in der Hilfe (beim Beispiel) hin gewiesen.

nur kann ich dann nicht mehr Formel und Vorlage kombinieren.

Doch, natürlich; nur solltest Du halt Texte mit anderen Texten
verknüpfen, und nicht versuchen, sie zu Zahlen zu addieren. <g>

Wolfgang

#6

Hallo Ernst, Boris, Wolfgang

=WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr.
Himmelfahrt"&T(VORLAGE("grau"));"leer"&T(VORLAGE("weiss")))

Ich hatte in alten Kalendern irgendwie eine andere Konstruktion. Was ich
noch nie genutzt habe ist in Formeln das "&". So klappt es auf jeden
Fall jetzt prima.
Wenn ich Muße habe werde ich die alte Konstruktion einmal genauer
untersuchen - vor allem interessiert mich, weshalb die ehemalige
Konstruktion auch unter LO 3.5.5 lief, die nahezu identische Übertragung
in einen anderen Kalender aber nicht mehr. Sicher irgendwo ein
Denkfehler meinerseits, so dass ich an der Stelle doch keine
Formatprobleme (Zeichen und Zahl) erzeugte.

Danke Euch alle, auch wenn ich jetzt nur einen Teil des Threads aufgreife.

Gruß

Robert

#7

Hallo

Die Formel: =WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"Chr.
Himmelfahrt";"")+VORLAGE(WENN((OSTERSONNTAG(Info.$C$3+1)+39)=A10;"grau";"weiss"))

Wenn eine Formel _Text_ zurückgibt wird eine Vorlage in der Syntax ...
& T(VORLAGE(...
...benutzt, gibt die Formel einen _Wert_ zurück nimmt man:
  + VORLAGE(...

abgesehen davon ist deine Formel furchtbar unflexibel, ein paar Tage
später musst du ja schon wieder *umschreiben* auf Pfingsten.

Allgemeingültig fürs ganze Jahr ginge das zb. mit:
=WENN(ZÄHLENWENN( feiertagsdaten ; A10);SVERWEIS(A10;
feiertage;2;0)&T(VORLAGE(SVERWEIS(A10;feiertage;3;0);"")

*feiertagsdaten* ist hier die erste Spalte einer zentralen
Feiertagsliste, *feiertage* ist die ganze 3-spaltige Liste mit Daten,
Feiertagsnamen und Vorlagennamen.

Werner

#8

Hallo Werner,

abgesehen davon ist deine Formel furchtbar unflexibel, ein paar Tage
später musst du ja schon wieder *umschreiben* auf Pfingsten.

Genau dem Problem habe ich mich durch Ergänzen von laufenden
WENN-Schleifen gestellt - wurden reichlich lang.

Allgemeingültig fürs ganze Jahr ginge das zb. mit:
=WENN(ZÄHLENWENN( feiertagsdaten ; A10);SVERWEIS(A10;
feiertage;2;0)&T(VORLAGE(SVERWEIS(A10;feiertage;3;0);"")

*feiertagsdaten* ist hier die erste Spalte einer zentralen
Feiertagsliste, *feiertage* ist die ganze 3-spaltige Liste mit Daten,
Feiertagsnamen und Vorlagennamen.

Danke für den Tip, werde das auch noch ausprobieren.
Mit Calc habe ich mich bisher wohl zu sehr "am Rande" beschäftigt.

Gruß

Robert