days since beginning of year

users
#1

How do I get the number of days since the beginning of year?

#2

Hello James,

How do I get the number of days since the beginning of year?

Use the DAYS function. See;
<https://help.libreoffice.org/latest/en-GB/text/scalc/01/func_days.html?DbPAR=CALC#bm_id3151328>

Note particularly the advice about NOT using locale specific date
formats due to the possibility of errors.

#3

I assume you're asking about how to get the days since the beginning of the
year given an existing date and that you're using LibreOffice Calc. With
this in mind, here is an example:

=DATEDIF("2020-12-31","2021-01-27","d")

The resulting value in the cell will be 27.

The first parameter is the starting date. Middle parameter is the current
date in question (I used Jan 27th in my example). The third parameter is
the interval Calc should use, which is days here, hence "d". Note that if
you use 2020-01-01 as the start date, then the 27th day of January would
actually only be the 26th day since Jan 1st, so you need to use a starting
date of the last day of the prior year.

Hope this helps!

#4

How about this?

=DAYS(CONCAT(YEAR(TODAY()),"-",MONTH(TODAY()),"-",DAY(TODAY())),CONCAT(YEAR(TODAY())-1,"-12-31"))

#5

How do I get the start date to be dynamically the current year?

Apr. 4, 2021 19:30:53 cspiess@ieee.org:

#6

I think you have dismantled today's date and then reassembled it.

Perhaps, more easily, this?
=DAYS(TODAY(),DATE(YEAR(TODAY()),1,1))+1
Or this?
=DAYS(TODAY(),YEAR(TODAY())&"-1-1")+1

I trust this helps.

Brian Barker

#7

How do I get the start date to be dynamically the current year?

Current year:
=YEAR(NOW())
First day of current year:
=DATE(YEAR(NOW());1;1)
Last day of last year:
=DATE(YEAR(NOW());1;1)-1
or
=DATE(YEAR(NOW())-1;12;31)
Days this year so far:
=NOW()-DATE(YEAR(NOW());1;1)+1
or
=DATEDIF(DATE(YEAR(NOW());1;1)-1;NOW();"d")
The last one returns an integer. If you want to use the first one to return
an integer, just modify it like this:
=INT(NOW()-DATE(YEAR(NOW());1;1)+1)

Kind regards

Johnny Rosenberg

#8

You already have the answer, as you have used the YEAR function in your
previous message.
So YEAR(cell) will give you just the year from the date expressed in "cell".