MittelwertWennS: geht das eigentlich ?

de-users
#1

Hallo,

Folgende Tabelle:
A B C D
Sig 1 Sig 2 Sig 3 Result
Bu Se Se 14365
Bu Bu Bu 4307
Bu Bu Bu 4292
Se Bu Bu 4132
Se Se Se 3942
Se Bu Bu 3235
Bu Se Se 2974
Se Bu Bu 2970
Se Bu Se 2787
Se Bu Bu 2574
Bu Se Se 2536
Bu Bu Bu 2368
Bu Se Bu 2054
Se Se Bu 1817

Meine Frage wären:
  Mittelwert, wenn B=C (Wert in B = Wert in C: Se&Se oder Bu&Bu)
oder
  Mittelwert, wenn B=C und B><A
oder
  Mittelwert, wenn B"=Se" und C"=Se" ODER
       B"=Bu" und C"=Bu"

Geht so etwas - wie ginge das?
Ich steh da momentan auf dem Schlauch :frowning:

#2

Hallo Gooly,

mein Lösungsansatz wäre hier die Aggregat Funktion zu verwenden. Aggregat 1 ist der Mittelwert. Wenn du mit der Option 6 Fehlerwerte ausschließt und dann deine Werte für den Mittelwert durch deine Bedingungen teilst, kommt immer dann wenn die Bedingung passt eine 1 und immer dann wenn es nicht passt eine 0. Wenn dein Wert durch die 1 geteilt wird bleibt er so wie er war. Durch Null führt das zu einem Fehler, der aber durch die Option 6 ignoriert wird. So geht es ganz einfach.

Hier die 3 Formeln:
Mittelwert, wenn B=C (Wert in B = Wert in C: Se&Se oder Bu&Bu) >>>>> =AGGREGAT(1;6;D2:D15/(B2:B15=C2:C15)) >>>>>> 4335,90909090909
Mittelwert, wenn B=C und B><A >>>>>> =AGGREGAT(1;6;D2:D15/((B2:B15=C2:C15)*(A2:A15<>B2:B15))) >>>>>> 4683,71428571429
Mittelwert, wenn B"=Se" und C"=Se" ODER B"=Bu" und C"=Bu" >>>>>> =AGGREGAT(1;6;D2:D15/((B2:B15="Se")*(C2:C15="Se")+(B2:B15="Bu")*(C2:C15="Bu"))) >>>>>> 4335,90909090909

Wobei die dritte und die erste Mittelwert Berechnung ja auf das gleiche hinaus kommt.

Ich habe dich Gooly nochmal zusätzlich zur Liste im Verteiler aufgenommen, da ich dir meine Beispieldatei mitgeschickt habe. Die würde bei der Liste nicht mit angezeigt werden.

Ich hoffe ich konnte dir weiter helfen.

mfg

Jürgen

#3

Hallo,

da man keinen Mittelwert aus Buchstaben "Bu" und "Se" bilden kann,
verstehe ich Deine Frage so:

Du möchtest einen Mittelwert der Spalte Result haben, allerdings nicht
von allen Werten, sondern nur von denen die in Spalte B und C gleich sind.

Mein Vorschlag:
Eine weitere Spalte (hier als Beispiel "E") anlegen und dort diese
Formel einfügen:
=WENN(B2=C2;D2;"")
Wenn B und C gleich ist dann den Wert von D (Result) übernehmen und wenn
nicht gleich, dann leer lassen.

Dann an der gewünschten Stelle die Formel =MITTELWERT(E2:E15) einfügen.
Die zusätzliche Spalte kann ja versteckt werden, falls diese Stört.

Vielleicht gibt es ja eine bessere Lösung mit MittelwertWennS oder so,
aber da steige ich nicht durch und jemand anderer kann einen eleganteren
Weg aufzeigen.

Ich hoffe es hilft

Schöne Grüße

#4

Vielen Dank!
Aggregat() kannte/kenne ich nicht und wäre auch nicht 'drauf gekommen.
Vielen Dank!

#5

Hallo Calli,

in LibreOffice 6 gab es leider einen Bug bei Aggregat. Dieser wurde erst bei der Version 7 gefixt.
Eigentlich habe ich das mal gewusst und hätte darauf achten müssen die Info gleich mitzugeben und dir auch eine Alternative anbieten.
Entschuldige bitte hierfür.

Ich habe jetzt in deiner Tabelle funktionierende Formeln eingefügt. So sollte es klappen.
Ich habe jetzt die Mittelwertwenn Funktion verwendet, die du von Anfang an wolltest.
Der Bereich in denen ich nach der Bedingung schauen möchte ist die Abfrage wie auch zuvor bei Aggregat. Hier kommen also immer Einsen bei wahr und Nullen bei falsch raus.
Die Bedingung ist dann "1". Also ich möchte den Mittelwert von den Zahlen in Spalte T bei denen bei meiner Abfrage eine 1 bzw. wahr raus kommt.
Damit dies so funktioniert, muss das ganze als Matrixformel geschrieben sein. Das brauchte es bei Aggregat nicht, da Aggregat mit Matrix arbeiten kann.
Mann kann die Formel auch innerhalb der Funktion Summenprodukt verwenden, dann klappt es auch mit der Matrix aber ohne die geschweiften Klammern.

Ich habe dir die drei Varianten aufgeführt. Bei Aggregat kommt bei dir in LO 6.4 entweder ein #DIV/0! Error oder quatsch raus. In Version 7.0 funktioniert es. Als Beweis ein Screenshot innerhalb der Datei!

Ich hoffe du kommst jetzt mit den Mittelwerten klar und meine Formeln entsprechen jetzt deinen Wünschen.
Bei Fragen bitte einfach nochmal schreiben.

mfg

Jürgen

#6

Mittlerweile habe ich von einer weiteren Lösung zu bedingten
Wahrscheinlichkeiten erfahren, die ich nicht 'verschweigen' möchte.

Aus den beiden Spalte mit Se oder Bu erzeuge ich eine neue Spalte C, die
beide 'addiert' =>
A B C
Se Bu => SeBu
Bu Se => BuSe
Bu Bu => BuBu
...
Statt die Spalten A und B abzufragen kann ich jetzt einfach C mit RegEx
abfragen (dazu unter Extras => Optionen => LO Calc => "Reguläre
Ausdrücke.." aktivieren).
MITTELWERTWENN($C$11:$C$84;"BuBu|SeSe";$T$11:$T$84))
Ist einfacher.
Info zu Regex ist hier:
https://help.libreoffice.org/7.0/de/text/shared/01/02100001.html?DbPAR=SHARED#bm_id3146765

Vielen Dank noch einmal,
Gooly