Verketten und IF Abfrage

de-users
#1

Hallo,

ich habe eine Tabelle wie folgt aufgebaut:

Master;Slave;Bestellnummer;Produktname;Ø-Innen [mm];Ø-Aussen [mm];Wandstärke [mm];Überdruck [bar];Unterdruck [bar];Biegeradius [mm];Gewicht [kg/m];Länge [m]
104800000000;104803800000;301-0038-0000;PROTAPE® PUR 301 AS;38;46;0,4;0,630;0,245;27;0,220;1

Die Daten werden miteinander verkettet um html code zu generieren. Es
geht hier insbesondere um die Spalte Wandstärke (0,4), gibt es eine
Möglichkeit dort eine IF Abfrage einzuarbeiten? Die Wandstärken
werden nicht bei allen Schläuchen benötigt.

=CONCATENATE("<li>Innendurchmesser: ";TEXT(E2;"0,00");"mm</li><li>Aussendurchmesser: ";TEXT(F2;"0,00");"mm</li><li>Wandstärke: ";G2;"mm</li><li>Überdruck: ";TEXT(H2;"0,000");"bar</li><li>Unterdruck: ";TEXT(I2;"0,000");"bar</li><li>Gewicht: ";TEXT(K2*L2;"0,000");"kg</li><li>Länge: ";L2;"m</li>":wink:

Ich habe das probiert mit if(G2>0...) und isblank aber es will nicht
funktionieren.

Ist Wandstärke leer, oder 0 soll er <li>Wandstärke: ";G2;"mm</li>
nicht "schreiben".

Danke für die Hilfe.

Mfg
Silvio

#2

Hey Silvio,

Hallo,

[..]
Ich habe das probiert mit if(G2>0...) und isblank aber es will nicht
funktionieren.

Was funktioniert denn daran nicht? Der Weg und die Formel ist schon korrekt. Müsste dann eben lauten:

=WENN(G2;"<li>Wandstärke: " & G2 & " mm</li>"; "")

Musst dann natürlich aus den anderen Strings die Teile entfernen, die hier eingebaut werden ;))

VG

Thomas

#3

Ergänzung:

Das Gleichheitszeichen (=) natürlich weglassen - das ist nur für die Formel alleine in einer Zelle;))

Also Dein String lautet dann:

=CONCATENATE("<li>Innendurchmesser: ";TEXT(E2;"0,00");"mm</li><li>Aussendurchmesser: ";TEXT(F2;"0,00");"mm</li>";WENN(G2;"<li>Wandstärke: " & G2 & " mm</li>"; "");"<li>Überdruck: ";TEXT(H2;"0,000");"bar</li><li>Unterdruck: ";TEXT(I2;"0,000");"bar</li><li>Gewicht: ";TEXT(K2*L2;"0,000");"kg</li><li>Länge: ";L2;"m</li>":wink:

#4

Hallo Silvio,

hast du denn ein englischsprachiges System? Wenn du deutsch als Sprache hast, musst du die deutschen Befehle VERKETTEN und WENN verwenden.
Ich habe ein ganz einfaches Beipaiel gemacht, das funktioniert:
=WENN(B1>0;VERKETTEN(A1;B1);A1)
die Spalte B entspricht deiner Spalte für die Wandstärke.

Gruß
Gerhard

#5

Ergänzung 2:

Und natürlich statt "wenn" bei Dir wahrscheinlich "if" - Du verwendest ja englische Bezeichnungen....

#6

Genau das alles funktioniert nicht, ich kenne die IF Funktionen nutze ich
relative häufig, auch CONCATENATE aber noch nie zusammen :slight_smile:

Wie du ohne verketten:
http://status.sisi-systems.ovh/501-1.png

Mit Verketten:
http://status.sisi-systems.ovh/501-2.png

=CONCATENATE("<li>Innendurchmesser: ";TEXT(E2;"0,00");"mm</li><li>Aussendurchmesser: ";TEXT(F2;"0,00");"mm</li>IF(G2>0;"<li>Wandstärke: " & G2 & " mm</li>"; "")<li>Überdruck: ";TEXT(H2;"0,000");"bar</li><li>Unterdruck: ";TEXT(I2;"0,000");"bar</li><li>Gewicht: ";TEXT(K2*L2;"0,000");"kg</li><li>Länge: ";L2;"m</li>";)))

=CONCATENATE("<li>Innendurchmesser: ";TEXT(E2;"0,00");"mm</li><li>Aussendurchmesser: ";TEXT(F2;"0,00");"mm</li>IF(G2>0;CONCATENATE("<li>Wandstärke: ";G2;"mm</li>");"")<li>Überdruck: ";TEXT(H2;"0,000");"bar</li><li>Unterdruck: ";TEXT(I2;"0,000");"bar</li><li>Gewicht: ";TEXT(K2*L2;"0,000");"kg</li><li>Länge: ";L2;"m</li>";))

Ich rätsel auch warum da einfach Klammern angehängt werden, nach Sublime
sind die alle korrekt geschlossen.

Mfg
Silvio

#7

Hey Silvio,

na, der Fehler liegt im deinem Verketten! Die Ifbedingung muss ein eigenständiges Element sein, also im Statement Verketten(...; IF(...);...) genau zwischen zwei Semikolons erscheinen. Das tut sie bei Deinen Beispielen beides mal nicht.

Viele Grüße

Thomas

#8

Ich hätte es so geschrieben:

=TEXTJOIN("</li><li>";1;"<li>Innendurchmesser: " & FIXED(E2) & "mm";"Aussendurchmesser: " & FIXED(F2) & "mm";IF(G2=0;"";"Wandstärke: " & G2 & "mm");"Überdruck: " & FIXED(H2;3) & "bar";"Unterdruck: " & FIXED(I2;3) & "bar"; "Gewicht: " & FIXED(K2*L2;3) & "kg";"Länge: " & L2 & "m</li>")

Verbinden / Textjoin ist seit LibreOffice 5.2 verfügbar.

mfg

Jürgen

#9

Hallo Thomas,

na, der Fehler liegt im deinem Verketten! Die Ifbedingung muss ein
eigenständiges Element sein, also im Statement Verketten(...;
IF(...);...) genau zwischen zwei Semikolons erscheinen. Das tut sie bei
Deinen Beispielen beides mal nicht.

na super das war es :slight_smile: ich habe diese Woche echt ein Problem mit
irgendwelchen Sonderzeichen :slight_smile:

Danke
Silvio